print_to_unit_actv Module Subroutine

  module subroutine print_to_unit_actv(this, unit, identifier)
    !! Interface for printing activation function details
    implicit none

    ! Arguments
    class(base_actv_type), intent(in) :: this
    !! Instance of the activation type
    integer, intent(in) :: unit
    !! Unit number for output
    character(*), intent(in), optional :: identifier
    !! Optional identifier for the activation function

    ! Local variables
    integer :: i
    !! Loop index
    type(onnx_attribute_type), allocatable, dimension(:) :: attributes
    !! Array of ONNX attributes


    attributes = this%export_attributes()

    if(present(identifier))then
       write(unit,'(3X,"ACTIVATION: ",A)') trim(identifier)
    else
       write(unit,'(3X,"ACTIVATION")')
    end if
    do i = 1, size(attributes)
       write(unit,'(6X,A," = ",A)') &
            trim(attributes(i)%name), trim(attributes(i)%val)
    end do
    write(unit,'(3X,"END ACTIVATION")')

  end subroutine print_to_unit_actv